, Un moniteur DB limité dans le temps

La commande STRDBMON vous permet de lancer des moniteurs de base de données, si vous lancez un moniteur privé (sur le travail en cours), il prendra fin quand le job se terminera.

Mais si vous lancez un moniteur public pour tous les travaux par exemple, comment l’arrêter, vous pouvez vouloir un moniteur tous les jour de 14h à 18h pour analyser les JOB ODBC ou autres.

Nous proposons un petit code que vous pourrez améliorer qui fera cette opération :

   PGM    parm(&fil &lib &dly)
/* Ce programme démarre un moniteur base de données */
/* pour les jobs ODBC , Pendant x secondes          */
/* ce job doit être soumis dans QSYSNOMAX           */
/* par exemple                                      */
/* Paramètres */
    DCL        VAR(&FIL ) TYPE(*CHAR) LEN(10)
    DCL        VAR(&LIB ) TYPE(*CHAR) LEN(10)
    DCL        VAR(&DLY ) TYPE(*CHAR) LEN(06)
/* Variables de travail */
    DCL        &MSGID *CHAR LEN(7)
    DCL        &DATA *CHAR LEN(100)
    DCL        &ID  *CHAR LEN(10)
/* Contrôle des paramètres */
    chkobj &lib  *lib
    monmsg cpf9801 exec(do)
             SNDUSRMSG  MSG('Bibliothèque,' *BCAT &LIB *BCAT +
                          'inexistante') MSGTYPE(*INFO)
                          return
    enddo
    chkobj &lib/&fil *file
    monmsg cpf9801 exec(do)
    goto suite
    enddo
             SNDUSRMSG  MSG('Monitor,' *BCAT &fil *BCAT +
                          'déjà existant') MSGTYPE(*INFO)
                          return
    suite:
   /* démarrage */
             STRDBMON   OUTFILE(&LIB/&FIL) +
                          JOB(*ALL/QUSER/QZDASOINIT) +
                          HOSTVAR(*SECURE) COMMENT('ODBC JOBS')
   /* Lecture de l'id du moniteur  */
   /* message  CPI436A             */
             DOUNTIL    COND(&MSGID = 'CPI436A')
             RCVMSG     MSGQ(*PGMQ)           MSGDTA(&DATA) +
                          MSGID(&MSGID)
             enddo
             CHGVAR     VAR(&ID) VALUE(%SST(&DATA 29 10))
             SNDUSRMSG  MSG('Moniteur, ' *BCAT &ID *BCAT 'démarré') +
                          MSGTYPE(*INFO)
   /* Retardement de l'arrêt en secondes */
      DLYJOB     DLY(&dly)
             ENDDBMON   JOB(*ALL) MONID(&ID)
             SNDUSRMSG  MSG('Moniteur, ' *BCAT &ID *BCAT 'arrêté') +
                          MSGTYPE(*INFO)
           ENDPGM

Vous pouvez indiquer la bibliothèque et le fichier de sortie pour le monitor et le temps d’exécution en secondes

Vous pouvez changer les filtres au niveau du STRDBMON en précisant ce que vous voulez analyser

vous pouvez faire une commande comme ceci pour lancer plus facilement votre programme ! 

CMD        PROMPT('DBMON limité dans le temps')          
 PARM       KWD(FILE) TYPE(*NAME) LEN(10) MIN(1) +        
              PROMPT('Fichier')                           
 PARM       KWD(LIB) TYPE(*NAME) LEN(10) MIN(1) +         
              PROMPT('Bibliothèque')                      
 PARM       KWD(DELAY) TYPE(*CHAR) LEN(06) DFT(000600) +  
              RANGE(000010 999999) MIN(0) PROMPT('Delay + 
              en secondes')

Conclusion

Vous pouvez le planifier dans votre Scheduler et indiquer par exemple un nom de fichier DBMAAMMJJ pour chaque jour, vous pourrez ainsi comparer au fil du temps ce qui ce passe sur cette période dans votre base de données.

Attention à bien le soumettre dans une file qui ne bloquera pas vos traitements, par exemple QSYSNOMAX ou QUSRNOMAX

/par